y86-64 Arkkitehtuuri¶

Rekisterit¶

• Yleiskäyttöisiä (GPR): %rax,%rcx, %rdx, %rbx, %rsi, %rdi, %r8-%r14
• Pinon alkupään osoite: %rbp
• Pinon osoitinrekisteri: %rsp
• Suorittimen tilarekisteri
• Ohjelmalaskuri (Program counter, PC) sisältää seuraavan suoritettavan käskyn muistiosoitteen.

Prosessorin tila¶

• Tilabitti asetetaan, kun suoritin saa keskeytyksen.
• Ohjelman ehdollinen toiminta (vertailuoperaattorit, hyppykäskyt, jne) perustuvat tilarekisterin bittien arvon vertailuun.
• Käskyn seurauksena aiheutuva virheellinen toiminto merkitään asettamalla tilabitti.

• ZF (zero flag): Ilmaisee oliko edellisen ALUn suorittaman operaation tulos 0. Usein tätä lippua käytetään yhtäsuuruuden toteamisessa.
• ZF=0, tulos erisuuri kuin 0
• ZF=1, kun tulos on 0

Esimerkiksi positiivisen ja positiivisen luvun vähennyslasku
  01111111
- 01111111
  --------
  00000000 ZF=1, koska tulos on 0

• SF (Sign flag): Oliko edellinen ALUn operaation tulos negatiivinen?
• SF=0, tulos > 0
• SF=1, tulos < 0

Esimerkiksi positiivisen ja negatiivisen luvun yhteenlasku
  00001111
  10000001
  --------
  10010000 Nyt merkkibitti MSB on 1, joten tulos negatiivinen -> SF=1

• OF (Overflow flag): Ilmaisee tapahtuiko operaatiossa ylivuoto, joka tarkoittaa sitä, että laskutoimitus ei mahdu tulosrekisterin lukualueeseen.
• OF=0, ei ylivuotoa
• OF=1, ylivuoto tapahtui

Lasketaan yhteen kaksi positiivista lukua:
  01111111
  01111111
  --------
  11111110 Tulos ei mahdu positiiviseen lukualueeseen, MSB = 1 -> OF=1
           Lisäksi -> SF=1

Lasketaan yhteen kaksi negatiivistiä lukua:
  10000001
+ 10000001
  --------
 100000010 Nyt MSB =1, mutta se leikkautuu pois
  00000010 Tulos on positiivinen luku -> OF=1 

• Osana tilarekisteria on y86:n ohjelman suorituksen tila (status code, STAT), joka voi olla:
• AOK: Kaikki ok
• HLT: Prosessori pysähdyksissä
• ADR: Osoitettiin väärään muistiosoitteeseen
• INS: Käskyssä virhe / väärä käsky

Osoitusmuodot¶

• Suora osoitus (Immediate) vakioarvoille: $numero. Esimerkiksi $1,$-13 tai $0x1F.
• Esimerkki: talletetaan luku 1 rekisteriin rsi irmovq $1,%rsi
• Rekisteriosoitus (Register) jossa operandi on rekisterin sisältö: %rekisteri.
• Esimerkiksi talletetaan rekisteri rax arvo rekisteriin rbx rrmovq %rax,%rbx
• Epäsuora osoitus (Memory) jossa operandi haetaan rekisterin osoittamasta muistipaikasta, merkitään sulkeilla: (%rekisteri).
• Sulkeiden edessä voi vielä olla numero n(%rekisteri) (base + displacement), jossa tapauksessa osoitetaan muistipaikkaa rekisterin arvo + n. Tätä käytetään tyypillisesti pinomuistin lukemisessa.
• Esimerkiksi haetaan muistista arvo muistipaikasta %rax:n arvo ja tallennetaan se rekisteriin %rbx: mrmovq (%rax),%rbx
• Esimerkiksi haetaan muistista arvo muistipaikasta %rax:n arvo -16 ja tallennetaan se rekisteriin %rbx: mrmovq -16(%rax),%rbx
• Tätä osoitusmuotoa vastaa C-kielen osoitin eli (%rekisteri) voisi olla C-kielessä *rekisteri

Keskusmuisti¶

Pinomuisti¶

# Pinon alustus
irmovq $100,%rbp # Pinon alkuosoite muistissa
irmovq $100,%rsp # Pinon nykyisen (päällimäisen) muistipaikan osoite

irmovq $2,%rax
pushq %rax        # Viedään pinoon rax:n arvo
# Nyt rekisterit muuttuvat seuraavasti
%rax = 2
%rbp = 100
%rsp = 92        # Vietiin muistia sanan pituuden verran

irmovq $3,%rbx
pushq %rbx        # Viedään pinoon rbx:n arvo
# Nyt rekisterit muuttuvat seuraavasti
%rbx = 3
%rbp = 100
%rsp = 84        # Vietiin muistia sanan pituuden verran

popq %rcx         # Luetaan pinosta päällimmäinen arvo
# Nyt rekisterit muuttuvat seuraavasti
%rcx = 3
%rbp = 100
%rsp = 92        # Luettu sana poistui pinosta

y86-64 Assembly-kieli¶

Pino¶

.pos 0
    irmovq Pino,%rbp # Pinon alkuosoite rekistereihin
    irmovq Pino,%rsp # Pinon nykyisen muistipaikan osoite 

.pos 0x100
Pino:

1. Pinoon viemme tavaraa pushq käskyllä, joka ottaa operandikseen sen rekisterin arvon, mistä arvo haetaan. Pino-osoittimen osoittamasta kohtaan muistia tallennetaan rekisterin arvo ja päivitetään pino-osoitinta vastaavasti.
2. Pinosta haetaan tavaraa popq-käskyllä, joka tallentaa pino-osoittimen osoittamasta kohdasta arvon operandina annettuun rekisteriin.

   irmovq $32,%rax # Varataan tilaa neljälle sanalle x 8 tavua = 32 tavua
   subq $32, %rsp # Pino-osoitin siirtyy alaspäin 32 tavua

Aritmeettiset operaatiot¶

• addq %r1,%r2: yhteenlasku r2 = r2 + r1
• subq %r1,%r2: vähennyslasku r2 = r2 - r1
• andq %r1,%r2: JA-operaatio r2 = r2 & r1
• xorq %r1,%r2: ERI-operaatio r2 = r2 ^ r1

    addq %r10,%rsi # %rsi = %rsi + %r10
    subq %r9,%rsi  # %rsi = %rsi - %r9
    andq %rax,%rbx # %rbx = %rax & %rbx
    xorq %rsp,%rbp # %rbp = %rsp ^ %rbp

Siirto-operaatiot¶

• irmovq: vakioarvo (i=immediate) rekisteriin (r=register): i->r
• rrmovq: rekisteristä rekisteriin r->r
• mrmovq muistista (m=memory) rekisteriin m->r
• rmmovq: rekisteristä muistiin r->m

    irmovq $4    , %rsi    # Sijoitetaan numeroarvo 4 rekisteriin %rsi
    rrmovq %rax  , %rsp    # Sijoitetaan %rax:n arvo %rsp:hen
    mrmovq (%rdi), %r10    # Haetaan arvo rekisterin %rdi osoittamasta paikasta ja sijoitetaan %r10:n
    rmmovq %rcx  , 8(%rdx) #  Sijoitetaan %rcx:n arvo osoitteeseen %rdx:n arvo + 8

• cmove (equal): toteutuu kun ZF=1
• cmovne (not equal): toteutuu kun ~ZF, eli ZF=0
• cmovl (less): toteutuu kun SF^OF
• cmovle (less or equal): toteutuu kun (SF^OF) | ZF
• cmovge (greater or equal): toteutuu kun ~(SF^OF)
• cmovg (greater): toteutuu kun ~(SF^OF) & ~ZF

.pos 0
main:
    irmovq $3,%rax    # a=3
    irmovq $2,%rbx    # b=2
                      # Testataan a == b ?     
    subq %rax,%rbx    # Vähennyslaskulla rbx = rbx - rax 
                      # Jos rbx > rax, tilaliput eivät muutu
                      # Jos rbx < rax, SF=1 ja OF=1
                      # Jos rbx = rax, ZF=1
    cmove %rax,%rcx   # Nyt jos ZF=1, sijoitetaan rcx = rax
                      # muutoin käsky ei tee mitään

Hyppykäskyt¶

• jmp: Hyppää ehdoitta
• je yhtäsuuri (equal) toteutuu kun ZF=1
• jne erisuuri (not equal) toteutuu kun ~ZF eli ZF=0
• jle pienempi tai yhtäsuuri (less or equal) toteutuu kun (SF^OF) | ZF
• jl pienempi (less) toteutuu kun SF^OF
• jge suurempi tai yhtäsuuri (greater or equal) toteutuu kun ~(SF^OF)
• jg suurempi (greater) toteutuu kun ~(SF^OF) & ~ZF

int64_t rcx = 10;   // Silmukkamuuttuja
int64_t rdx = 1;    // apumuuttuja (jolla vähennetään 1)
while (rcx !=0) {   // Testaus rcx != 0
   tee_jotain();    // Aliohjelmakutsu
   rcx = rcx - rdx; // Vähennyslasku rcx = rcx - rdx
}

    irmovq $0x10,%rcx # Silmukkamuuttuja
    irmovq $0x1,%rdx  # apumuuttuja (jolla vähennetään 1)
loop:
    call tee_jotain   # Aliohjelmakutsu, kts alla. 
    subq %rdx,%rcx    # Vähennyslasku rcx = rcx - rdx: jos rcx = 0 -> ZF=1
    jne loop          # Testaus rcx != 0: Jos erisuuri, eli ZF=0, hyppää loop
    halt              # Muutoin lopeta ohjelma

Aliohjelmat¶

1. Aliohjelman suoritus tehdään hyppykäskyllä sen muistiosoitteeseen, josta paluu takaisin kutsuvaan koodiin. Ohjelman suoritus aliohjelman"hypyn" jälkeen jatkuu siis siitä mihin se jäi..
2. Miten tehdään muuttujien (ts. parametrien) välitys aliohjelmalle ja aliohjelman paluuarvo?
3. Miten varataan muistia aliohjelman paikallisille muuttujille?

Aliohjelman suoritus¶

1. Ensiksi, ennen hyppyä aliohjelmaan, tallennetaan nykyinen ohjelman tila (rekisterit + PC) pinoon. Tämä on tärkeää siksi, että voimme palata aliohjelmasta samaan suorittimen tilaan mistä aliohjelmaa lähdettiin suorittamaan. Joskun käytämme samoja rekistereitä, niin aliohjelma muuttaisi niiden arvoja, eikä kutsuvan ohjelman suoritus enää jatkuisi siitä tilasta mihin jäätiin!
• Osa rekistereistä on myös määritelty siten, että niissä olevan arvon ylläpitämisestä on vastuussa joko aliohjelman kutsuja tai aliohjelma itse.
2. Aliohjelman hyppykutsu tallentaa pinoon paluuosoitteen, ts. osoitteen josta kutsuvan ohjelman suoritus jatkuu kun aliohjelman suoritus on loppunut.
3. Aliohjelman parametrit voidaan välittää joko rekisterien tai pinon kautta. Jos käytetään rekistereitä, niille on sovittu järjestys jota tulisi käyttää. Eli ensimmäinen parametri menee rekisteriin rdi ja toinen parametri rekisteriin rsi, jne. Koska rekistereitä on rajallinen määrä, on mahdollista välittää vain muutamia arvoja. Tähän tarjoaa pino apua, eli voimme viedä parametrit pinoon, josta aliohjelma ne lukee.
• Funktion paikallisille muuttujille voidaan ennen funktion kutsua varata muistia siirtämällä pino-osoitinta eteenpäin tarvittava tavumäärä. Luemme arvot sitten pinosta käyttäen epäsuoraa osoitusta.
4. Aliohjelmassa ja sitä kutsuvassa pitää huolehtia, että pinosta haetaan täsmälleen sama joukko tietoa, kun sinne tallennettiin. Aliohjelmakutsussa pino on siis tilapäinen tietovarasto.
5. Aliohjelmasta poistumiskäsky lopuksi hakee pinosta kutsuneen ohjelman seuraavan koodirivin osoitteen ja palaa suorittamaan sitä. Tässä yhteydessä myös muistin tila tulee palauttaa entiselleen, jotta paluuosoite haetaan oikeasta paikasta.

.pos 0
init:
    irmovq pino,%rsp  # Pinon alustus (muistiosoitteeseen 0x100)
    irmovq pino,%rbp
main:                 # Pääohjelma
    irmovq $0x11,%rdi # Argumentit rekistereihin
    irmovq $0x11,%rsi
    call laske    
    halt
    
.pos 0x40
laske:
    addq %rsi,%rdi    # Argumentit aliohjelmassa
    ret

.pos 0x400
pino:

.pos 0
    irmovq Pino,%rsp      # Alustetaan pino
    irmovq Pino,%rbp
main:
    irmovq $0x11,%rax
    pushq %rax            # vie 1. argumentti pinoon
    irmovq $0x22,%rax
    pushq %rax            # vie 2. argumentti pinoon
    pushq %rax            # varataan tilaa funktion paluuarvolle
    call laske            # aliohjelmakutsu
    popq %rax             # haetaan paluuarvo
    popq %rax             # tyhjennetään pino
    popq %rax
    halt

.pos 0x40
laske:
    mrmovq 24(%rsp),%rdx  # 1. argumentti pinosta (kolme muistipaikkaa x 8 tavua = 24)
    mrmovq 16(%rsp),%rcx  # 2. argumentti pinosta (kaksi muistipaikkaa x 8 tavua = 16)
    addq %rcx,%rdx
    rmmovq %rdx,8(%rsp)   # paluuarvo pinoon sovittuun paikkaan
    ret

.pos 0x400
Pino:

Muita käskyjä¶

Kääntämistä ohjaavat käskyt¶

• nimi: Symbolinen nimi tätä seuraavalle koodilohkolle. Esimerkiksi aliohjelmalle voidaan antaa symbolinen nimi. Nimi häviää koodista käännösvaiheessa ja korvautuu varsinaisella muistiosoitteella.

main:
    ...
funktio1:
    ...
funktio2:
    ...

• .pos Asettaa tätä seuraavan koodin / koodilohkon alkavan mistä tahansa annetusta muistiosoitteesta.

.pos 0 # Koodi (tässä itse nimetty main-funktio) alkaa muistiosoitteesta 0
main: 
    ...
.pos 0x100 # funktio1:sen koodi alkaa muistiosoitteesta 0x100
funktio1:
    ...

• .align tasaa muistiosoitteen annettuun sanan pituuteen. Jos muistiin asetattavan arvon koko on pienempi kuin sana, täytetään sen perään nollia niin kauan että se vastaa sanan pituutta. Tämä on hyödyllinen ominaisuus esimerkiksi taulukkojen yhteydessä, mutta sitä ei yleensä tarvita.

• .quad-käskyllä voidaan muistiin asettaa tietoa. Asetus tapahtuu ennen koodin ajamista, eli tämä toimii ikäänkuin massamuistina, josta voimme lukea dataa.

.pos 0x80
.align 8 # ryhmitellään muisti 8:n tavun mittaisiin osoitteisiin
.quad 0x1234 # 2-tavuinen luku
.quad 0x5678 # 2-tavuinen luku

...
0x80: 0x3412000000000000
0x88: 0x7856000000000000
...

Lopuksi¶